mirror of https://github.com/ecmwf/eccodes.git
Autotools make dist: add linux distro
This commit is contained in:
Shahram Najm
parent
8e3b2f2244
commit
08b5112ec8
|
|
@ -0,0 +1,77 @@
|
|||
# SYNOPSIS
|
||||
#
|
||||
# AX_LINUX_DISTRIBUTION
|
||||
#
|
||||
# DESCRIPTION
|
||||
#
|
||||
# Try to detect the name and version of the Linux distribution where the software is being run
|
||||
#
|
||||
# In configure.in:
|
||||
#
|
||||
# dnl For my rpm.m4 macros
|
||||
# AC_SUBST(LINUX_DISTRIBUTION_NAME)
|
||||
# AC_SUBST(LINUX_DISTRIBUTION_VERSION)
|
||||
#
|
||||
# Daniel Varela <dvarela@ecmwf.int> 2011
|
||||
# Version 1.1 (2011-11-11)
|
||||
|
||||
|
||||
dnl AX_LINUX_DISTRIBUTION
|
||||
dnl Figure out the Linux distribution where the software is being built
|
||||
dnl automake target
|
||||
|
||||
AC_DEFUN([AX_LINUX_DISTRIBUTION],
|
||||
[dnl
|
||||
AC_REQUIRE([AC_CANONICAL_HOST])
|
||||
HOST_CPU=${host_cpu}
|
||||
HOST_VENDOR=${host_vendor}
|
||||
HOST_OS=${host_os}
|
||||
|
||||
if test x$HOST_OS = "xlinux-gnu"
|
||||
then
|
||||
AC_MSG_CHECKING(for Linux distribution )
|
||||
|
||||
# This works for Fedora, RedHat and Slackware
|
||||
for f in /etc/fedora-release /etc/redhat-release /etc/slackware-release
|
||||
do
|
||||
if test -f $f; then
|
||||
distro=`cat $f`
|
||||
break
|
||||
fi
|
||||
done
|
||||
|
||||
# This works in Ubuntu (11 at least)
|
||||
if test -f /etc/lsb-release; then
|
||||
distro=`cat /etc/lsb-release | grep DISTRIB_ID | awk -F= '{print $2}' `
|
||||
distro_version=`cat /etc/lsb-release | grep DISTRIB_RELEASE | awk -F= '{print $2}' `
|
||||
fi
|
||||
|
||||
# For SuSE
|
||||
if test -f /etc/SuSE-release; then
|
||||
distro=`cat /etc/SuSE-release | head -1`
|
||||
#distro_version=`cat /etc/SuSE-release | tail -1 | awk -F= '{print $2}' `
|
||||
fi
|
||||
|
||||
# At least Debian has this
|
||||
if test -f /etc/issue.net -a "x$distro" = x; then
|
||||
distro=`cat /etc/issue.net | head -1`
|
||||
fi
|
||||
|
||||
# Everything else
|
||||
if test "x$distro" = x; then
|
||||
distro="Unknown Linux"
|
||||
fi
|
||||
|
||||
LINUX_DISTRIBUTION_NAME=$distro
|
||||
LINUX_DISTRIBUTION_VERSION=$distro_version
|
||||
AC_MSG_RESULT($LINUX_DISTRIBUTION_NAME $LINUX_DISTRIBUTION_VERSION)
|
||||
|
||||
else
|
||||
LINUX_DISTRIBUTION_NAME=$HOST_OS
|
||||
LINUX_DISTRIBUTION_VERSION=""
|
||||
AC_MSG_NOTICE(OS is non-Linux UNIX $HOST_OS.)
|
||||
fi
|
||||
|
||||
AC_SUBST(LINUX_DISTRIBUTION_NAME)
|
||||
AC_SUBST(LINUX_DISTRIBUTION_VERSION)
|
||||
])
|
||||
|
|
@ -0,0 +1,325 @@
|
|||
# ===========================================================================
|
||||
# http://www.gnu.org/software/autoconf-archive/ax_python_devel.html
|
||||
# ===========================================================================
|
||||
#
|
||||
# SYNOPSIS
|
||||
#
|
||||
# AX_PYTHON_DEVEL([version])
|
||||
#
|
||||
# DESCRIPTION
|
||||
#
|
||||
# Note: Defines as a precious variable "PYTHON_VERSION". Don't override it
|
||||
# in your configure.ac.
|
||||
#
|
||||
# This macro checks for Python and tries to get the include path to
|
||||
# 'Python.h'. It provides the $(PYTHON_CPPFLAGS) and $(PYTHON_LDFLAGS)
|
||||
# output variables. It also exports $(PYTHON_EXTRA_LIBS) and
|
||||
# $(PYTHON_EXTRA_LDFLAGS) for embedding Python in your code.
|
||||
#
|
||||
# You can search for some particular version of Python by passing a
|
||||
# parameter to this macro, for example ">= '2.3.1'", or "== '2.4'". Please
|
||||
# note that you *have* to pass also an operator along with the version to
|
||||
# match, and pay special attention to the single quotes surrounding the
|
||||
# version number. Don't use "PYTHON_VERSION" for this: that environment
|
||||
# variable is declared as precious and thus reserved for the end-user.
|
||||
#
|
||||
# This macro should work for all versions of Python >= 2.1.0. As an end
|
||||
# user, you can disable the check for the python version by setting the
|
||||
# PYTHON_NOVERSIONCHECK environment variable to something else than the
|
||||
# empty string.
|
||||
#
|
||||
# If you need to use this macro for an older Python version, please
|
||||
# contact the authors. We're always open for feedback.
|
||||
#
|
||||
# LICENSE
|
||||
#
|
||||
# Copyright (c) 2009 Sebastian Huber <sebastian-huber@web.de>
|
||||
# Copyright (c) 2009 Alan W. Irwin <irwin@beluga.phys.uvic.ca>
|
||||
# Copyright (c) 2009 Rafael Laboissiere <rafael@laboissiere.net>
|
||||
# Copyright (c) 2009 Andrew Collier <colliera@ukzn.ac.za>
|
||||
# Copyright (c) 2009 Matteo Settenvini <matteo@member.fsf.org>
|
||||
# Copyright (c) 2009 Horst Knorr <hk_classes@knoda.org>
|
||||
#
|
||||
# This program is free software: you can redistribute it and/or modify it
|
||||
# under the terms of the GNU General Public License as published by the
|
||||
# Free Software Foundation, either version 3 of the License, or (at your
|
||||
# option) any later version.
|
||||
#
|
||||
# This program is distributed in the hope that it will be useful, but
|
||||
# WITHOUT ANY WARRANTY; without even the implied warranty of
|
||||
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
|
||||
# Public License for more details.
|
||||
#
|
||||
# You should have received a copy of the GNU General Public License along
|
||||
# with this program. If not, see <http://www.gnu.org/licenses/>.
|
||||
#
|
||||
# As a special exception, the respective Autoconf Macro's copyright owner
|
||||
# gives unlimited permission to copy, distribute and modify the configure
|
||||
# scripts that are the output of Autoconf when processing the Macro. You
|
||||
# need not follow the terms of the GNU General Public License when using
|
||||
# or distributing such scripts, even though portions of the text of the
|
||||
# Macro appear in them. The GNU General Public License (GPL) does govern
|
||||
# all other use of the material that constitutes the Autoconf Macro.
|
||||
#
|
||||
# This special exception to the GPL applies to versions of the Autoconf
|
||||
# Macro released by the Autoconf Archive. When you make and distribute a
|
||||
# modified version of the Autoconf Macro, you may extend this special
|
||||
# exception to the GPL to apply to your modified version as well.
|
||||
|
||||
#serial 8
|
||||
|
||||
AU_ALIAS([AC_PYTHON_DEVEL], [AX_PYTHON_DEVEL])
|
||||
AC_DEFUN([AX_PYTHON_DEVEL],[
|
||||
#
|
||||
# Allow the use of a (user set) custom python version
|
||||
#
|
||||
AC_ARG_VAR([PYTHON_VERSION],[The installed Python
|
||||
version to use, for example '2.3'. This string
|
||||
will be appended to the Python interpreter
|
||||
canonical name.])
|
||||
|
||||
AC_PATH_PROG([PYTHON],[python[$PYTHON_VERSION]])
|
||||
if test -z "$PYTHON"; then
|
||||
AC_MSG_ERROR([Cannot find python$PYTHON_VERSION in your system path])
|
||||
PYTHON_VERSION=""
|
||||
fi
|
||||
|
||||
#
|
||||
# Check for a version of Python >= 2.1.0
|
||||
#
|
||||
AC_MSG_CHECKING([for a version of Python >= '2.1.0'])
|
||||
ac_supports_python_ver=`$PYTHON -c "import sys; \
|
||||
ver = sys.version.split ()[[0]]; \
|
||||
print (ver >= '2.1.0')"`
|
||||
if test "$ac_supports_python_ver" != "True"; then
|
||||
if test -z "$PYTHON_NOVERSIONCHECK"; then
|
||||
AC_MSG_RESULT([no])
|
||||
AC_MSG_FAILURE([
|
||||
This version of the AC@&t@_PYTHON_DEVEL macro
|
||||
doesn't work properly with versions of Python before
|
||||
2.1.0. You may need to re-run configure, setting the
|
||||
variables PYTHON_CPPFLAGS, PYTHON_LDFLAGS, PYTHON_SITE_PKG,
|
||||
PYTHON_EXTRA_LIBS and PYTHON_EXTRA_LDFLAGS by hand.
|
||||
Moreover, to disable this check, set PYTHON_NOVERSIONCHECK
|
||||
to something else than an empty string.
|
||||
])
|
||||
else
|
||||
AC_MSG_RESULT([skip at user request])
|
||||
fi
|
||||
else
|
||||
AC_MSG_RESULT([yes])
|
||||
fi
|
||||
|
||||
#
|
||||
# if the macro parameter ``version'' is set, honour it
|
||||
#
|
||||
if test -n "$1"; then
|
||||
AC_MSG_CHECKING([for a version of Python $1])
|
||||
ac_supports_python_ver=`$PYTHON -c "import sys; \
|
||||
ver = sys.version.split ()[[0]]; \
|
||||
print (ver $1)"`
|
||||
if test "$ac_supports_python_ver" = "True"; then
|
||||
AC_MSG_RESULT([yes])
|
||||
else
|
||||
AC_MSG_RESULT([no])
|
||||
AC_MSG_ERROR([this package requires Python $1.
|
||||
If you have it installed, but it isn't the default Python
|
||||
interpreter in your system path, please pass the PYTHON_VERSION
|
||||
variable to configure. See ``configure --help'' for reference.
|
||||
])
|
||||
PYTHON_VERSION=""
|
||||
fi
|
||||
fi
|
||||
|
||||
#
|
||||
# Check if you have distutils, else fail
|
||||
#
|
||||
AC_MSG_CHECKING([for the distutils Python package])
|
||||
ac_distutils_result=`$PYTHON -c "import distutils" 2>&1`
|
||||
if test -z "$ac_distutils_result"; then
|
||||
AC_MSG_RESULT([yes])
|
||||
else
|
||||
AC_MSG_RESULT([no])
|
||||
AC_MSG_ERROR([cannot import Python module "distutils".
|
||||
Please check your Python installation. The error was:
|
||||
$ac_distutils_result])
|
||||
PYTHON_VERSION=""
|
||||
fi
|
||||
|
||||
#
|
||||
# Check for Python include path
|
||||
#
|
||||
AC_MSG_CHECKING([for Python include path])
|
||||
if test -z "$PYTHON_CPPFLAGS"; then
|
||||
python_path=`$PYTHON -c "import distutils.sysconfig; \
|
||||
print (distutils.sysconfig.get_python_inc ());"`
|
||||
if test -n "${python_path}"; then
|
||||
python_path="-I$python_path"
|
||||
fi
|
||||
PYTHON_CPPFLAGS=$python_path
|
||||
fi
|
||||
AC_MSG_RESULT([$PYTHON_CPPFLAGS])
|
||||
AC_SUBST([PYTHON_CPPFLAGS])
|
||||
|
||||
#
|
||||
# Check for Python library path
|
||||
#
|
||||
AC_MSG_CHECKING([for Python library path])
|
||||
if test -z "$PYTHON_LDFLAGS"; then
|
||||
# (makes two attempts to ensure we've got a version number
|
||||
# from the interpreter)
|
||||
ac_python_version=`cat<<EOD | $PYTHON -
|
||||
|
||||
# join all versioning strings, on some systems
|
||||
# major/minor numbers could be in different list elements
|
||||
from distutils.sysconfig import *
|
||||
ret = ''
|
||||
for e in get_config_vars ('VERSION'):
|
||||
if (e != None):
|
||||
ret += e
|
||||
print (ret)
|
||||
EOD`
|
||||
|
||||
if test -z "$ac_python_version"; then
|
||||
if test -n "$PYTHON_VERSION"; then
|
||||
ac_python_version=$PYTHON_VERSION
|
||||
else
|
||||
ac_python_version=`$PYTHON -c "import sys; \
|
||||
print (sys.version[[:3]])"`
|
||||
fi
|
||||
fi
|
||||
|
||||
# Make the versioning information available to the compiler
|
||||
AC_DEFINE_UNQUOTED([HAVE_PYTHON], ["$ac_python_version"],
|
||||
[If available, contains the Python version number currently in use.])
|
||||
|
||||
# First, the library directory:
|
||||
ac_python_libdir=`cat<<EOD | $PYTHON -
|
||||
|
||||
# There should be only one
|
||||
import distutils.sysconfig
|
||||
for e in distutils.sysconfig.get_config_vars ('LIBDIR'):
|
||||
if e != None:
|
||||
print (e)
|
||||
break
|
||||
EOD`
|
||||
|
||||
# Before checking for libpythonX.Y, we need to know
|
||||
# the extension the OS we're on uses for libraries
|
||||
# (we take the first one, if there's more than one fix me!):
|
||||
ac_python_soext=`$PYTHON -c \
|
||||
"import distutils.sysconfig; \
|
||||
print (distutils.sysconfig.get_config_vars('SO')[[0]])"`
|
||||
|
||||
# Now, for the library:
|
||||
ac_python_soname=`$PYTHON -c \
|
||||
"import distutils.sysconfig; \
|
||||
print (distutils.sysconfig.get_config_vars('LDLIBRARY')[[0]])"`
|
||||
|
||||
# Strip away extension from the end to canonicalize its name:
|
||||
ac_python_library=`echo "$ac_python_soname" | sed "s/${ac_python_soext}$//"`
|
||||
|
||||
# This small piece shamelessly adapted from PostgreSQL python macro;
|
||||
# credits goes to momjian, I think. I'd like to put the right name
|
||||
# in the credits, if someone can point me in the right direction... ?
|
||||
#
|
||||
if test -n "$ac_python_libdir" -a -n "$ac_python_library" \
|
||||
-a x"$ac_python_library" != x"$ac_python_soname"
|
||||
then
|
||||
# use the official shared library
|
||||
ac_python_library=`echo "$ac_python_library" | sed "s/^lib//"`
|
||||
PYTHON_LDFLAGS="-L$ac_python_libdir -l$ac_python_library"
|
||||
else
|
||||
# old way: use libpython from python_configdir
|
||||
ac_python_libdir=`$PYTHON -c \
|
||||
"from distutils.sysconfig import get_python_lib as f; \
|
||||
import os; \
|
||||
print (os.path.join(f(plat_specific=1, standard_lib=1), 'config'));"`
|
||||
PYTHON_LDFLAGS="-L$ac_python_libdir -lpython$ac_python_version"
|
||||
fi
|
||||
|
||||
if test -z "PYTHON_LDFLAGS"; then
|
||||
AC_MSG_ERROR([
|
||||
Cannot determine location of your Python DSO. Please check it was installed with
|
||||
dynamic libraries enabled, or try setting PYTHON_LDFLAGS by hand.
|
||||
])
|
||||
fi
|
||||
fi
|
||||
AC_MSG_RESULT([$PYTHON_LDFLAGS])
|
||||
AC_SUBST([PYTHON_LDFLAGS])
|
||||
|
||||
#
|
||||
# Check for site packages
|
||||
#
|
||||
AC_MSG_CHECKING([for Python site-packages path])
|
||||
if test -z "$PYTHON_SITE_PKG"; then
|
||||
PYTHON_SITE_PKG=`$PYTHON -c "import distutils.sysconfig; \
|
||||
print (distutils.sysconfig.get_python_lib(0,0));"`
|
||||
fi
|
||||
AC_MSG_RESULT([$PYTHON_SITE_PKG])
|
||||
AC_SUBST([PYTHON_SITE_PKG])
|
||||
|
||||
#
|
||||
# libraries which must be linked in when embedding
|
||||
#
|
||||
AC_MSG_CHECKING(python extra libraries)
|
||||
if test -z "$PYTHON_EXTRA_LIBS"; then
|
||||
PYTHON_EXTRA_LIBS=`$PYTHON -c "import distutils.sysconfig; \
|
||||
conf = distutils.sysconfig.get_config_var; \
|
||||
print (conf('LOCALMODLIBS') + ' ' + conf('LIBS') + ' ' + conf('SYSLIBS'))"`
|
||||
fi
|
||||
AC_MSG_RESULT([$PYTHON_EXTRA_LIBS])
|
||||
AC_SUBST(PYTHON_EXTRA_LIBS)
|
||||
|
||||
#
|
||||
# linking flags needed when embedding
|
||||
#
|
||||
AC_MSG_CHECKING(python extra linking flags)
|
||||
if test -z "$PYTHON_EXTRA_LDFLAGS"; then
|
||||
PYTHON_EXTRA_LDFLAGS=`$PYTHON -c "import distutils.sysconfig; \
|
||||
conf = distutils.sysconfig.get_config_var; \
|
||||
print (conf('LINKFORSHARED'))"`
|
||||
fi
|
||||
AC_MSG_RESULT([$PYTHON_EXTRA_LDFLAGS])
|
||||
AC_SUBST(PYTHON_EXTRA_LDFLAGS)
|
||||
|
||||
#
|
||||
# final check to see if everything compiles alright
|
||||
#
|
||||
AC_MSG_CHECKING([consistency of all components of python development environment])
|
||||
# save current global flags
|
||||
ac_save_LIBS="$LIBS"
|
||||
ac_save_CPPFLAGS="$CPPFLAGS"
|
||||
LIBS="$ac_save_LIBS $PYTHON_LDFLAGS $PYTHON_EXTRA_LDFLAGS $PYTHON_EXTRA_LIBS"
|
||||
CPPFLAGS="$ac_save_CPPFLAGS $PYTHON_CPPFLAGS"
|
||||
AC_LANG_PUSH([C])
|
||||
AC_LINK_IFELSE([
|
||||
AC_LANG_PROGRAM([[#include <Python.h>]],
|
||||
[[Py_Initialize();]])
|
||||
],[pythonexists=yes],[pythonexists=no])
|
||||
AC_LANG_POP([C])
|
||||
# turn back to default flags
|
||||
CPPFLAGS="$ac_save_CPPFLAGS"
|
||||
LIBS="$ac_save_LIBS"
|
||||
|
||||
AC_MSG_RESULT([$pythonexists])
|
||||
|
||||
if test ! "x$pythonexists" = "xyes"; then
|
||||
AC_MSG_FAILURE([
|
||||
Could not link test program to Python. Maybe the main Python library has been
|
||||
installed in some non-standard library path. If so, pass it to configure,
|
||||
via the LDFLAGS environment variable.
|
||||
Example: ./configure LDFLAGS="-L/usr/non-standard-path/python/lib"
|
||||
============================================================================
|
||||
ERROR!
|
||||
You probably have to install the development version of the Python package
|
||||
for your distribution. The exact name of this package varies among them.
|
||||
============================================================================
|
||||
])
|
||||
PYTHON_VERSION=""
|
||||
fi
|
||||
|
||||
#
|
||||
# all done!
|
||||
#
|
||||
])
|
||||
|
|
@ -0,0 +1,258 @@
|
|||
# ===========================================================================
|
||||
# http://www.gnu.org/software/autoconf-archive/ax_rpm_init.html
|
||||
# ===========================================================================
|
||||
#
|
||||
# SYNOPSIS
|
||||
#
|
||||
# AX_RPM_INIT
|
||||
#
|
||||
# DESCRIPTION
|
||||
#
|
||||
# Setup variables for creation of rpms. It will define several variables
|
||||
# useful for creating rpms on a system where rpms are supported.
|
||||
# Currently, I requires changes to Makefile.am to function properly (see
|
||||
# the example below).
|
||||
#
|
||||
# Also note that I do not use any non-UNIX OSs (and for the most part, I
|
||||
# only use RedHat), so this is probably generally not useful for other
|
||||
# systems.
|
||||
#
|
||||
# Required setup:
|
||||
#
|
||||
# In configure.in:
|
||||
#
|
||||
# dnl For my rpm.m4 macros
|
||||
# RPM_RELEASE=1
|
||||
# AC_SUBST(RPM_RELEASE)
|
||||
#
|
||||
# AX_RPM_INIT
|
||||
# dnl Enable or disable the rpm making rules in Makefile.am
|
||||
# AM_CONDITIONAL(MAKE_RPMS, test x$make_rpms = xtrue)
|
||||
#
|
||||
# Furthermore, the %GNUconfigure rpm macro has a problem in that it does
|
||||
# not define CXXFLAGS for the target system correctly, so for compiling
|
||||
# C++ code, add the following line _before_ calling AC_PROG_CXX:
|
||||
#
|
||||
# dnl This is a little hack to make this work with rpm better (see mysql++.spec.in)
|
||||
# test -z "$CXXFLAGS" && CXXFLAGS="${CFLAGS}"
|
||||
#
|
||||
# Changes to Makefile.am (I am trying to get rid of this step; suggestions
|
||||
# invited):
|
||||
#
|
||||
# if MAKE_RPMS
|
||||
# rpm: @RPM_TARGET@
|
||||
#
|
||||
# .PHONY: rpm
|
||||
#
|
||||
# $(RPM_TARGET): $(DISTFILES)
|
||||
# ${MAKE} dist
|
||||
# -mkdir -p $(RPM_DIR)/SRPMS
|
||||
# -mkdir -p `dirname $(RPM_TARGET)`
|
||||
# $(RPM_PROG) $(RPM_ARGS) $(RPM_TARBALL)
|
||||
# @echo Congratulations, $(RPM_TARGET) "(and friends)" should now exist.
|
||||
# else
|
||||
# endif
|
||||
#
|
||||
# Also, it works best with a XXXX.spec.in file like the following (this is
|
||||
# way down on the wishlist, but a program to generate the skeleton spec.in
|
||||
# much like autoscan would just kick butt!):
|
||||
#
|
||||
# ---------- 8< ----------
|
||||
# # -*- Mode:rpm-spec -*-
|
||||
# # mysql++.spec.in
|
||||
# Summary: Your package description goes here
|
||||
# %define rel @RPM_RELEASE@
|
||||
#
|
||||
# %define version @VERSION@
|
||||
# %define pkgname @PACKAGE@
|
||||
# %define prefix /usr
|
||||
#
|
||||
# %define lt_release @LT_RELEASE@
|
||||
# %define lt_version @LT_CURRENT@.@LT_REVISION@.@LT_AGE@
|
||||
#
|
||||
# # This is a hack until I can figure out how to better handle replacing
|
||||
# # autoconf macros... (gotta love autoconf...)
|
||||
# %define __aclocal aclocal || aclocal -I ./macros
|
||||
# %define configure_args @RPM_CONFIGURE_ARGS@
|
||||
#
|
||||
# Name: %{pkgname}
|
||||
# Version: %{version}
|
||||
# Release: %{rel}
|
||||
#
|
||||
# Copyright: LGPL
|
||||
# Group: # your group name goes here
|
||||
# Source: %{pkgname}-%{version}.tar.gz
|
||||
# Requires: # additional requirements
|
||||
# Buildroot: /tmp/%{pkgname}-root
|
||||
# URL: http://yoururl.go.here
|
||||
# Prefix: %{prefix}
|
||||
# BuildArchitectures: # Target platforms, i.e., i586
|
||||
# Packager: Your Name <youremail@your.address>
|
||||
#
|
||||
# %description
|
||||
# Your package description
|
||||
#
|
||||
# %changelog
|
||||
#
|
||||
# %prep
|
||||
# %setup
|
||||
# #%patch
|
||||
#
|
||||
# %build
|
||||
# %GNUconfigure %{configure_args}
|
||||
# # This is why we copy the CFLAGS to the CXXFLAGS in configure.in
|
||||
# # CFLAGS="%{optflags}" CXXFLAGS="%{optflags}" ./configure %{_target_platform} --prefix=%{prefix}
|
||||
# make
|
||||
#
|
||||
# %install
|
||||
# # To make things work with BUILDROOT
|
||||
# if [ "$RPM_BUILD_ROOT" != "/tmp/%{pkgname}-root" ]
|
||||
# then
|
||||
# echo
|
||||
# echo @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
|
||||
# echo @ @
|
||||
# echo @ RPM_BUILD_ROOT is not what I expected. Please clean it yourself. @
|
||||
# echo @ @
|
||||
# echo @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
|
||||
# echo
|
||||
# else
|
||||
# echo Cleaning RPM_BUILD_ROOT: "$RPM_BUILD_ROOT"
|
||||
# rm -rf "$RPM_BUILD_ROOT"
|
||||
# fi
|
||||
# make DESTDIR="$RPM_BUILD_ROOT" install
|
||||
#
|
||||
# %clean
|
||||
# # Call me paranoid, but I do not want to be responsible for nuking
|
||||
# # someone's harddrive!
|
||||
# if [ "$RPM_BUILD_ROOT" != "/tmp/%{pkgname}-root" ]
|
||||
# then
|
||||
# echo
|
||||
# echo @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
|
||||
# echo @ @
|
||||
# echo @ RPM_BUILD_ROOT is not what I expected. Please clean it yourself. @
|
||||
# echo @ @
|
||||
# echo @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
|
||||
# echo
|
||||
# else
|
||||
# echo Cleaning RPM_BUILD_ROOT: "$RPM_BUILD_ROOT"
|
||||
# rm -rf "$RPM_BUILD_ROOT"
|
||||
# fi
|
||||
#
|
||||
# %files
|
||||
# %defattr(-, root, root)
|
||||
# # Your application file list goes here
|
||||
# # %{prefix}/lib/lib*.so*
|
||||
# %doc COPYRIGHT ChangeLog README AUTHORS NEWS
|
||||
# %doc doc/*
|
||||
#
|
||||
# # If you install a library
|
||||
# %post -p /sbin/ldconfig
|
||||
#
|
||||
# # If you install a library
|
||||
# %postun -p /sbin/ldconfig
|
||||
#
|
||||
# %package devel
|
||||
# Summary: Development files for %{pkgname}
|
||||
# Group: Applications/Databases
|
||||
# %description devel
|
||||
# Development files for %{pkgname}.
|
||||
#
|
||||
# %files devel
|
||||
# %defattr(-, root, root)
|
||||
# # Your development files go here
|
||||
# # Programmers documentation goes here
|
||||
# %doc doc
|
||||
#
|
||||
# # end of file
|
||||
# ---------- >8 ----------
|
||||
#
|
||||
# LICENSE
|
||||
#
|
||||
# Copyright (c) 2008 Dale K. Hawkins <dhawkins@cdrgts.com>
|
||||
#
|
||||
# Copying and distribution of this file, with or without modification, are
|
||||
# permitted in any medium without royalty provided the copyright notice
|
||||
# and this notice are preserved. This file is offered as-is, without any
|
||||
# warranty.
|
||||
|
||||
# Modified by Daniel Varela <dvarela@ecmwf.int> 2011
|
||||
|
||||
#serial 5
|
||||
|
||||
dnl AX_RPM_INIT
|
||||
dnl Figure out how to create rpms for this system and setup for an
|
||||
dnl automake target
|
||||
|
||||
AU_ALIAS([AM_RPM_INIT], [AX_RPM_INIT])
|
||||
AC_DEFUN([AX_RPM_INIT],
|
||||
[dnl
|
||||
AC_REQUIRE([AC_CANONICAL_HOST])
|
||||
RPM_HOST_CPU=${host_cpu}
|
||||
RPM_HOST_VENDOR=${host_vendor}
|
||||
RPM_HOST_OS=${host_os}
|
||||
|
||||
dnl Find the RPM program
|
||||
AC_ARG_WITH(rpmbuild-prog,[ --with-rpmbuild-prog=PROG Which rpmbuild to use (optional)],
|
||||
rpmbuild_prog="$withval", rpmbuild_prog="")
|
||||
|
||||
AC_ARG_WITH(rpmbuild-extra-args, [ --with-rpmbuild-extra-args=ARGS Run rpmbuild with extra arguments (defaults to none)],
|
||||
rpmbuild_extra_args="$withval", rpmbuild_extra_args="")
|
||||
|
||||
AC_ARG_WITH(rpm-release, [ --with-rpm-release=NUMBER The rpms will use this release number (defaults to 1)],
|
||||
rpm_release="$withval", rpm_release=1)
|
||||
|
||||
RPM_TARGET=""
|
||||
RPM_RELEASE=$rpm_release
|
||||
|
||||
AC_PATH_PROG(RPMBUILD_PROG, rpmbuild, no)
|
||||
no_rpm=no
|
||||
|
||||
if test "$RPMBUILD_PROG" = "no"
|
||||
then
|
||||
echo rpm package building is disabled. Set the path to the rpmbuild program using --with-rpmbuild-prog=PROG
|
||||
no_rpm=yes
|
||||
RPM_MAKE_RULES=""
|
||||
else
|
||||
# AC_MSG_CHECKING(how rpmbuild sets %{_rpmdir})
|
||||
rpmdir=`$RPMBUILD_PROG --eval %{_rpmdir} 2> /dev/null`
|
||||
if test x$rpmdir = x"%{_rpmdir}" ; then
|
||||
AC_MSG_RESULT([not set (cannot build rpms?)])
|
||||
echo *** Could not determine the value of %{_rpmdir}
|
||||
echo *** This could be because it is not set, or your version of rpm does not set it
|
||||
echo *** It must be set in order to generate the correct rpm generation commands
|
||||
echo ***
|
||||
echo *** You might still be able to create rpms, but I could not automate it for you
|
||||
echo *** BTW, if you know this is wrong, please help to improve the rpm.m4 module
|
||||
echo *** Send corrections, updates and fixes to dhawkins@cdrgts.com. Thanks.
|
||||
# else
|
||||
# AC_MSG_RESULT([$rpmdir])
|
||||
fi
|
||||
AC_MSG_CHECKING(how rpm sets %{_rpmfilename})
|
||||
rpmfilename=`$RPMBUILD_PROG --eval %{_rpmfilename} 2> /dev/null | sed "s/%{ARCH}/${RPM_HOST_CPU}/g" | sed "s/%{NAME}/$PACKAGE/g" | sed "s/%{VERSION}/${VERSION}/g" | sed "s/%{RELEASE}/${RPM_RELEASE}/g"`
|
||||
AC_MSG_RESULT([$rpmfilename])
|
||||
|
||||
RPM_DIR=${rpmdir}
|
||||
RPM_TARGET=$rpmfilename
|
||||
RPM_ARGS="-ta $rpmbuild_extra_args"
|
||||
RPM_TARBALL=${PACKAGE}-${VERSION}.tar.gz
|
||||
|
||||
fi
|
||||
|
||||
case "${no_rpm}" in
|
||||
yes) make_rpms=false;;
|
||||
no) make_rpms=true;;
|
||||
*) AC_MSG_WARN([bad value ${no_rpm} for no_rpm (not making rpms)])
|
||||
make_rpms=false;;
|
||||
esac
|
||||
|
||||
AC_SUBST(RPM_DIR)
|
||||
AC_SUBST(RPM_TARGET)
|
||||
AC_SUBST(RPM_ARGS)
|
||||
AC_SUBST(RPM_TARBALL)
|
||||
AC_SUBST(RPM_HOST_CPU)
|
||||
AC_SUBST(RPM_HOST_VENDOR)
|
||||
AC_SUBST(RPM_HOST_OS)
|
||||
|
||||
RPM_CONFIGURE_ARGS=${ac_configure_args}
|
||||
AC_SUBST(RPM_CONFIGURE_ARGS)
|
||||
])
|
||||
Loading…
Reference in New Issue